#defaultView:Graph
SELECT ?author1 ?author1Label ?rgb ?author2 ?author2Label
WITH {
  # Find works with the topic
  SELECT ?work WHERE {
    ?work wdt:P921 / (wdt:P31* / wdt:P279* | wdt:P361+ | wdt:P1269+) wd:Q3025883 .
  }
} AS %works
WITH {
  # Limit the number of authors to the most prolific ones
  SELECT (COUNT(?work) AS ?count) ?author1 WHERE {
    INCLUDE %works
    ?work wdt:P50 ?author1 .
  }
  GROUP BY ?author1
  ORDER BY DESC(?count)
  LIMIT 25
} AS %authors
WITH {
  # Limit the number of coauthorships
  SELECT (COUNT(*) AS ?coauthorships) ?author1 ?author2 WHERE {
    INCLUDE %works
    INCLUDE %authors
    ?work wdt:P50 ?author1 , ?author2 .
    FILTER (?author1 != ?author2) 
  } 
  GROUP BY ?author1 ?author2
  ORDER BY DESC(?coauthorships)
  LIMIT 500
} AS %coauthorships
WHERE {
  # Color and label the nodes
  INCLUDE %coauthorships
  OPTIONAL { ?author1 wdt:P21 ?gender1 . }
  BIND( IF(?gender1 = wd:Q6581097, "3182BD", "E6550D") AS ?rgb)
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en,fr,de,ru,es,zh,jp".
  }
}